Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 1 | // Rom layout and bios assembler to C interface. |
| 2 | // |
Kevin O'Connor | f8e176c | 2009-05-06 23:33:32 -0400 | [diff] [blame] | 3 | // Copyright (C) 2008,2009 Kevin O'Connor <kevin@koconnor.net> |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 4 | // Copyright (C) 2002 MandrakeSoft S.A. |
| 5 | // |
Kevin O'Connor | b1b7c2a | 2009-01-15 20:52:58 -0500 | [diff] [blame] | 6 | // This file may be distributed under the terms of the GNU LGPLv3 license. |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 7 | |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 8 | |
| 9 | /**************************************************************** |
| 10 | * Include of 16bit C code |
| 11 | ****************************************************************/ |
| 12 | |
Kevin O'Connor | 7453453 | 2008-05-12 18:28:58 -0400 | [diff] [blame] | 13 | .code16gcc |
Kevin O'Connor | 3dba4c2 | 2011-01-29 11:26:54 -0500 | [diff] [blame] | 14 | #include "ccode.16.s" |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 15 | |
Kevin O'Connor | f8e176c | 2009-05-06 23:33:32 -0400 | [diff] [blame] | 16 | #include "config.h" // CONFIG_* |
| 17 | #include "ioport.h" // PORT_A20 |
| 18 | #include "bregs.h" // CR0_* |
| 19 | #include "cmos.h" // CMOS_RESET_CODE |
Kevin O'Connor | 3dba4c2 | 2011-01-29 11:26:54 -0500 | [diff] [blame] | 20 | #include "asm-offsets.h" // BREGS_* |
Kevin O'Connor | f8e176c | 2009-05-06 23:33:32 -0400 | [diff] [blame] | 21 | #include "entryfuncs.S" // ENTRY_* |
Kevin O'Connor | 7453453 | 2008-05-12 18:28:58 -0400 | [diff] [blame] | 22 | |
Kevin O'Connor | 1d01951 | 2008-03-11 21:21:47 -0400 | [diff] [blame] | 23 | |
| 24 | /**************************************************************** |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 25 | * Call trampolines |
| 26 | ****************************************************************/ |
| 27 | |
| 28 | // Place CPU into 32bit mode from 16bit mode. |
Kevin O'Connor | 4057f98 | 2010-11-25 08:52:50 -0500 | [diff] [blame] | 29 | // %edx = return location (in 32bit mode) |
Kevin O'Connor | ad90159 | 2009-12-13 11:25:25 -0500 | [diff] [blame] | 30 | // Clobbers: ecx, flags, segment registers, cr0, idt/gdt |
Kevin O'Connor | d67a703 | 2009-01-17 19:37:26 -0500 | [diff] [blame] | 31 | DECLFUNC transition32 |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 32 | transition32: |
Kevin O'Connor | ad90159 | 2009-12-13 11:25:25 -0500 | [diff] [blame] | 33 | movl %eax, %ecx |
Kevin O'Connor | 9caf786 | 2009-02-27 20:14:05 -0500 | [diff] [blame] | 34 | |
Kevin O'Connor | f094ba8 | 2009-04-13 19:30:27 -0400 | [diff] [blame] | 35 | // Disable irqs (and clear direction flag) |
| 36 | cli |
| 37 | cld |
| 38 | |
| 39 | // Disable nmi |
| 40 | movl $CMOS_RESET_CODE|NMI_DISABLE_BIT, %eax |
| 41 | outb %al, $PORT_CMOS_INDEX |
| 42 | inb $PORT_CMOS_DATA, %al |
| 43 | |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 44 | // enable a20 |
Kevin O'Connor | d9a8b2d | 2008-11-16 09:17:02 -0500 | [diff] [blame] | 45 | inb $PORT_A20, %al |
| 46 | orb $A20_ENABLE_BIT, %al |
| 47 | outb %al, $PORT_A20 |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 48 | |
| 49 | // Set segment descriptors |
Kevin O'Connor | 6e5b4a4 | 2008-12-06 13:03:52 -0500 | [diff] [blame] | 50 | lidtw %cs:pmode_IDT_info |
| 51 | lgdtw %cs:rombios32_gdt_48 |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 52 | |
Kevin O'Connor | 3eac009 | 2008-11-16 09:59:32 -0500 | [diff] [blame] | 53 | // Enable protected mode |
| 54 | movl %cr0, %eax |
| 55 | orl $CR0_PE, %eax |
| 56 | movl %eax, %cr0 |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 57 | |
Kevin O'Connor | 6e5b4a4 | 2008-12-06 13:03:52 -0500 | [diff] [blame] | 58 | // start 32bit protected mode code |
Kevin O'Connor | 1492708 | 2008-11-08 19:07:49 -0500 | [diff] [blame] | 59 | ljmpl $SEG32_MODE32_CS, $(BUILD_BIOS_ADDR + 1f) |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 60 | |
| 61 | .code32 |
| 62 | 1: |
| 63 | // init data segments |
Kevin O'Connor | 1492708 | 2008-11-08 19:07:49 -0500 | [diff] [blame] | 64 | movl $SEG32_MODE32_DS, %eax |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 65 | movw %ax, %ds |
| 66 | movw %ax, %es |
| 67 | movw %ax, %ss |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 68 | movw %ax, %fs |
| 69 | movw %ax, %gs |
| 70 | |
Kevin O'Connor | ad90159 | 2009-12-13 11:25:25 -0500 | [diff] [blame] | 71 | movl %ecx, %eax |
Kevin O'Connor | 4057f98 | 2010-11-25 08:52:50 -0500 | [diff] [blame] | 72 | jmpl *%edx |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 73 | |
Kevin O'Connor | 752151b | 2009-12-10 21:16:07 -0500 | [diff] [blame] | 74 | // Place CPU into 16bit mode from 32bit mode. |
Kevin O'Connor | 4057f98 | 2010-11-25 08:52:50 -0500 | [diff] [blame] | 75 | // %edx = return location (in 16bit mode) |
Kevin O'Connor | ad90159 | 2009-12-13 11:25:25 -0500 | [diff] [blame] | 76 | // Clobbers: ecx, flags, segment registers, cr0, idt/gdt |
Kevin O'Connor | 752151b | 2009-12-10 21:16:07 -0500 | [diff] [blame] | 77 | DECLFUNC transition16 |
| 78 | .global transition16big |
| 79 | transition16: |
Kevin O'Connor | ad90159 | 2009-12-13 11:25:25 -0500 | [diff] [blame] | 80 | movl %eax, %ecx |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 81 | |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 82 | // restore data segment limits to 0xffff |
Kevin O'Connor | 6e5b4a4 | 2008-12-06 13:03:52 -0500 | [diff] [blame] | 83 | movl $SEG32_MODE16_DS, %eax |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 84 | movw %ax, %ds |
| 85 | movw %ax, %es |
| 86 | movw %ax, %ss |
| 87 | movw %ax, %fs |
| 88 | movw %ax, %gs |
| 89 | |
Kevin O'Connor | ffb81a4 | 2009-04-13 19:44:55 -0400 | [diff] [blame] | 90 | #if CONFIG_DISABLE_A20 |
Kevin O'Connor | 1a72e2e | 2008-11-11 22:03:55 -0500 | [diff] [blame] | 91 | // disable a20 |
Kevin O'Connor | d9a8b2d | 2008-11-16 09:17:02 -0500 | [diff] [blame] | 92 | inb $PORT_A20, %al |
| 93 | andb $~A20_ENABLE_BIT, %al |
| 94 | outb %al, $PORT_A20 |
Kevin O'Connor | ffb81a4 | 2009-04-13 19:44:55 -0400 | [diff] [blame] | 95 | #endif |
Kevin O'Connor | 1a72e2e | 2008-11-11 22:03:55 -0500 | [diff] [blame] | 96 | |
| 97 | // Jump to 16bit mode |
| 98 | ljmpw $SEG32_MODE16_CS, $1f |
| 99 | |
Kevin O'Connor | 752151b | 2009-12-10 21:16:07 -0500 | [diff] [blame] | 100 | transition16big: |
Kevin O'Connor | ad90159 | 2009-12-13 11:25:25 -0500 | [diff] [blame] | 101 | movl %eax, %ecx |
Kevin O'Connor | 6e5b4a4 | 2008-12-06 13:03:52 -0500 | [diff] [blame] | 102 | |
| 103 | movl $SEG32_MODE16BIG_DS, %eax |
| 104 | movw %ax, %ds |
| 105 | movw %ax, %es |
| 106 | movw %ax, %ss |
| 107 | movw %ax, %fs |
| 108 | movw %ax, %gs |
| 109 | |
Kevin O'Connor | 0f78889 | 2010-07-25 14:04:01 -0400 | [diff] [blame] | 110 | ljmpw $SEG32_MODE16BIG_CS, $1f |
Kevin O'Connor | 6e5b4a4 | 2008-12-06 13:03:52 -0500 | [diff] [blame] | 111 | |
Kevin O'Connor | 1a72e2e | 2008-11-11 22:03:55 -0500 | [diff] [blame] | 112 | .code16gcc |
| 113 | 1: |
Kevin O'Connor | 3eac009 | 2008-11-16 09:59:32 -0500 | [diff] [blame] | 114 | // Disable protected mode |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 115 | movl %cr0, %eax |
Kevin O'Connor | 3eac009 | 2008-11-16 09:59:32 -0500 | [diff] [blame] | 116 | andl $~CR0_PE, %eax |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 117 | movl %eax, %cr0 |
| 118 | |
| 119 | // far jump to flush CPU queue after transition to real mode |
Kevin O'Connor | e3677b1 | 2008-07-04 15:29:23 -0400 | [diff] [blame] | 120 | ljmpw $SEG_BIOS, $2f |
Kevin O'Connor | 21e930b | 2008-03-01 09:49:37 -0500 | [diff] [blame] | 121 | |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 122 | 2: |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 123 | // restore IDT to normal real-mode defaults |
Kevin O'Connor | 6e5b4a4 | 2008-12-06 13:03:52 -0500 | [diff] [blame] | 124 | lidtw %cs:rmode_IDT_info |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 125 | |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 126 | // Clear segment registers |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 127 | xorw %ax, %ax |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 128 | movw %ax, %fs |
| 129 | movw %ax, %gs |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 130 | movw %ax, %es |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 131 | movw %ax, %ds |
| 132 | movw %ax, %ss // Assume stack is in segment 0 |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 133 | |
Kevin O'Connor | ad90159 | 2009-12-13 11:25:25 -0500 | [diff] [blame] | 134 | movl %ecx, %eax |
Kevin O'Connor | 4057f98 | 2010-11-25 08:52:50 -0500 | [diff] [blame] | 135 | jmpl *%edx |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 136 | |
Kevin O'Connor | 21e930b | 2008-03-01 09:49:37 -0500 | [diff] [blame] | 137 | // Call a 16bit function from 16bit mode with a specified cpu register state |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 138 | // %eax = address of struct bregs |
Kevin O'Connor | 9caf786 | 2009-02-27 20:14:05 -0500 | [diff] [blame] | 139 | // Clobbers: %e[bcd]x, %e[ds]i, flags |
Kevin O'Connor | d67a703 | 2009-01-17 19:37:26 -0500 | [diff] [blame] | 140 | DECLFUNC __call16 |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 141 | __call16: |
Kevin O'Connor | 9caf786 | 2009-02-27 20:14:05 -0500 | [diff] [blame] | 142 | // Save %eax, %ebp |
| 143 | pushl %ebp |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 144 | pushl %eax |
| 145 | |
| 146 | // Setup for iretw call |
Kevin O'Connor | 273e8ae | 2009-01-19 19:56:07 -0500 | [diff] [blame] | 147 | pushw %cs |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 148 | pushw $1f // return point |
Kevin O'Connor | 952974e | 2008-11-16 18:14:33 -0500 | [diff] [blame] | 149 | pushw BREGS_flags(%eax) // flags |
Kevin O'Connor | 9f98542 | 2009-09-09 11:34:39 -0400 | [diff] [blame] | 150 | pushl BREGS_code(%eax) // CS:IP |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 151 | |
| 152 | // Load calling registers. |
Kevin O'Connor | 952974e | 2008-11-16 18:14:33 -0500 | [diff] [blame] | 153 | movl BREGS_edi(%eax), %edi |
| 154 | movl BREGS_esi(%eax), %esi |
Kevin O'Connor | 7da210c | 2009-05-16 23:57:08 -0400 | [diff] [blame] | 155 | movl BREGS_ebp(%eax), %ebp |
Kevin O'Connor | 952974e | 2008-11-16 18:14:33 -0500 | [diff] [blame] | 156 | movl BREGS_ebx(%eax), %ebx |
| 157 | movl BREGS_edx(%eax), %edx |
| 158 | movl BREGS_ecx(%eax), %ecx |
| 159 | movw BREGS_es(%eax), %es |
| 160 | movw BREGS_ds(%eax), %ds |
| 161 | movl %ss:BREGS_eax(%eax), %eax |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 162 | |
| 163 | // Invoke call |
| 164 | iretw // XXX - just do a lcalll |
| 165 | 1: |
| 166 | // Store flags, eax, ecx |
| 167 | pushfw |
| 168 | pushl %eax |
| 169 | movl 0x06(%esp), %eax |
Kevin O'Connor | 952974e | 2008-11-16 18:14:33 -0500 | [diff] [blame] | 170 | movl %ecx, %ss:BREGS_ecx(%eax) |
| 171 | movw %ds, %ss:BREGS_ds(%eax) |
Kevin O'Connor | cbbb667 | 2008-03-08 13:04:10 -0500 | [diff] [blame] | 172 | movw %ss, %cx |
Kevin O'Connor | 952974e | 2008-11-16 18:14:33 -0500 | [diff] [blame] | 173 | movw %cx, %ds // Restore %ds == %ss |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 174 | popl %ecx |
Kevin O'Connor | 952974e | 2008-11-16 18:14:33 -0500 | [diff] [blame] | 175 | movl %ecx, BREGS_eax(%eax) |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 176 | popw %cx |
Kevin O'Connor | 952974e | 2008-11-16 18:14:33 -0500 | [diff] [blame] | 177 | movw %cx, BREGS_flags(%eax) |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 178 | |
| 179 | // Store remaining registers |
Kevin O'Connor | 952974e | 2008-11-16 18:14:33 -0500 | [diff] [blame] | 180 | movw %es, BREGS_es(%eax) |
| 181 | movl %edi, BREGS_edi(%eax) |
| 182 | movl %esi, BREGS_esi(%eax) |
Kevin O'Connor | 7da210c | 2009-05-16 23:57:08 -0400 | [diff] [blame] | 183 | movl %ebp, BREGS_ebp(%eax) |
Kevin O'Connor | 952974e | 2008-11-16 18:14:33 -0500 | [diff] [blame] | 184 | movl %ebx, BREGS_ebx(%eax) |
| 185 | movl %edx, BREGS_edx(%eax) |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 186 | |
Kevin O'Connor | 9caf786 | 2009-02-27 20:14:05 -0500 | [diff] [blame] | 187 | // Remove %eax, restore %ebp |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 188 | popl %eax |
Kevin O'Connor | 9caf786 | 2009-02-27 20:14:05 -0500 | [diff] [blame] | 189 | popl %ebp |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 190 | |
| 191 | retl |
| 192 | |
Kevin O'Connor | 752151b | 2009-12-10 21:16:07 -0500 | [diff] [blame] | 193 | // Call a 16bit function from 32bit mode. |
| 194 | // %eax = address of struct bregs |
| 195 | // Clobbers: %e[bcd]x, %e[ds]i, flags, segment registers, idt/gdt |
| 196 | DECLFUNC __call16_from32 |
| 197 | .global __call16big_from32 |
| 198 | .code32 |
| 199 | __call16_from32: |
Kevin O'Connor | 4057f98 | 2010-11-25 08:52:50 -0500 | [diff] [blame] | 200 | movl $1f, %edx |
Kevin O'Connor | 752151b | 2009-12-10 21:16:07 -0500 | [diff] [blame] | 201 | jmp transition16 |
| 202 | __call16big_from32: |
Kevin O'Connor | 4057f98 | 2010-11-25 08:52:50 -0500 | [diff] [blame] | 203 | movl $1f, %edx |
Kevin O'Connor | 752151b | 2009-12-10 21:16:07 -0500 | [diff] [blame] | 204 | jmp transition16big |
| 205 | |
| 206 | // Make call. |
| 207 | .code16gcc |
| 208 | 1: calll __call16 |
| 209 | // Return via transition32 |
Kevin O'Connor | 4057f98 | 2010-11-25 08:52:50 -0500 | [diff] [blame] | 210 | movl $(2f + BUILD_BIOS_ADDR), %edx |
Kevin O'Connor | 752151b | 2009-12-10 21:16:07 -0500 | [diff] [blame] | 211 | jmp transition32 |
Kevin O'Connor | 4057f98 | 2010-11-25 08:52:50 -0500 | [diff] [blame] | 212 | .code32 |
| 213 | 2: retl |
Kevin O'Connor | 752151b | 2009-12-10 21:16:07 -0500 | [diff] [blame] | 214 | |
Kevin O'Connor | 4057f98 | 2010-11-25 08:52:50 -0500 | [diff] [blame] | 215 | .code16gcc |
Kevin O'Connor | 79dde65 | 2009-04-13 19:26:43 -0400 | [diff] [blame] | 216 | // IRQ trampolines |
| 217 | .macro IRQ_TRAMPOLINE num |
| 218 | DECLFUNC irq_trampoline_0x\num |
| 219 | irq_trampoline_0x\num : |
| 220 | int $0x\num |
| 221 | lretw |
| 222 | .endm |
| 223 | |
| 224 | IRQ_TRAMPOLINE 10 |
| 225 | IRQ_TRAMPOLINE 13 |
| 226 | IRQ_TRAMPOLINE 15 |
| 227 | IRQ_TRAMPOLINE 16 |
| 228 | IRQ_TRAMPOLINE 18 |
| 229 | IRQ_TRAMPOLINE 19 |
| 230 | |
| 231 | |
| 232 | /**************************************************************** |
Kevin O'Connor | 87b533b | 2011-07-10 22:35:07 -0400 | [diff] [blame] | 233 | * Misc. entry points. |
Kevin O'Connor | 79dde65 | 2009-04-13 19:26:43 -0400 | [diff] [blame] | 234 | ****************************************************************/ |
| 235 | |
Kevin O'Connor | 87b533b | 2011-07-10 22:35:07 -0400 | [diff] [blame] | 236 | // Resume (and reboot) entry point - called from entry_post |
| 237 | DECLFUNC entry_resume |
| 238 | entry_resume: |
Kevin O'Connor | 79dde65 | 2009-04-13 19:26:43 -0400 | [diff] [blame] | 239 | // Disable interrupts |
| 240 | cli |
| 241 | cld |
Kevin O'Connor | 79dde65 | 2009-04-13 19:26:43 -0400 | [diff] [blame] | 242 | // Use a stack in EBDA |
| 243 | movw $SEG_BDA, %ax |
| 244 | movw %ax, %ds |
| 245 | movw BDA_ebda_seg, %ax |
Kevin O'Connor | 87b533b | 2011-07-10 22:35:07 -0400 | [diff] [blame] | 246 | movw %ax, %ds |
Kevin O'Connor | 79dde65 | 2009-04-13 19:26:43 -0400 | [diff] [blame] | 247 | movw %ax, %ss |
| 248 | movl $EBDA_OFFSET_TOP_STACK, %esp |
Kevin O'Connor | 79dde65 | 2009-04-13 19:26:43 -0400 | [diff] [blame] | 249 | // Call handler. |
Kevin O'Connor | 79dde65 | 2009-04-13 19:26:43 -0400 | [diff] [blame] | 250 | jmp handle_resume |
| 251 | |
Kevin O'Connor | e54ee38 | 2009-07-26 19:33:13 -0400 | [diff] [blame] | 252 | // PMM entry point |
| 253 | DECLFUNC entry_pmm |
| 254 | entry_pmm: |
| 255 | pushl %esp // Backup %esp, then clear high bits |
| 256 | movzwl %sp, %esp |
| 257 | pushfl // Save registers clobbered by C code |
| 258 | cli |
| 259 | cld |
| 260 | pushl %eax |
| 261 | pushl %ecx |
| 262 | pushl %edx |
| 263 | pushw %es |
| 264 | pushw %ds |
| 265 | movw %ss, %cx // Move %ss to %ds |
| 266 | movw %cx, %ds |
Kevin O'Connor | 533b628 | 2011-07-16 13:13:12 -0400 | [diff] [blame] | 267 | movl $_cfunc32flat_handle_pmm, %eax // Setup: call32(handle_pmm, args, -1) |
| 268 | leal 28(%esp), %edx // %edx points to start of args |
| 269 | movl $-1, %ecx |
| 270 | calll call32 |
Kevin O'Connor | e54ee38 | 2009-07-26 19:33:13 -0400 | [diff] [blame] | 271 | movw %ax, 12(%esp) // Modify %ax:%dx to return %eax |
| 272 | shrl $16, %eax |
| 273 | movw %ax, 4(%esp) |
| 274 | popw %ds // Restore saved registers |
| 275 | popw %es |
| 276 | popl %edx |
| 277 | popl %ecx |
| 278 | popl %eax |
| 279 | popfl |
| 280 | popl %esp |
| 281 | lretw |
| 282 | |
Kevin O'Connor | 79dde65 | 2009-04-13 19:26:43 -0400 | [diff] [blame] | 283 | // PnP entry points |
Kevin O'Connor | d67a703 | 2009-01-17 19:37:26 -0500 | [diff] [blame] | 284 | DECLFUNC entry_pnp_real |
| 285 | .global entry_pnp_prot |
Kevin O'Connor | 0c3068d | 2008-12-21 17:51:36 -0500 | [diff] [blame] | 286 | entry_pnp_prot: |
| 287 | pushl %esp |
| 288 | jmp 1f |
| 289 | entry_pnp_real: |
| 290 | pushl %esp // Backup %esp, then clear high bits |
| 291 | movzwl %sp, %esp |
| 292 | 1: |
| 293 | pushfl // Save registers clobbered by C code |
Kevin O'Connor | e54ee38 | 2009-07-26 19:33:13 -0400 | [diff] [blame] | 294 | cli |
| 295 | cld |
Kevin O'Connor | 0c3068d | 2008-12-21 17:51:36 -0500 | [diff] [blame] | 296 | pushl %eax |
| 297 | pushl %ecx |
| 298 | pushl %edx |
| 299 | pushw %es |
| 300 | pushw %ds |
| 301 | movw %ss, %cx // Move %ss to %ds |
| 302 | movw %cx, %ds |
Kevin O'Connor | 752151b | 2009-12-10 21:16:07 -0500 | [diff] [blame] | 303 | leal 28(%esp), %eax // %eax points to start of u16 args |
Kevin O'Connor | 0c3068d | 2008-12-21 17:51:36 -0500 | [diff] [blame] | 304 | calll handle_pnp |
| 305 | movw %ax, 12(%esp) // Modify %eax to return %ax |
| 306 | popw %ds |
| 307 | popw %es |
| 308 | popl %edx |
| 309 | popl %ecx |
| 310 | popl %eax |
| 311 | popfl |
| 312 | popl %esp |
| 313 | lretw |
| 314 | |
Kevin O'Connor | 79dde65 | 2009-04-13 19:26:43 -0400 | [diff] [blame] | 315 | // APM entry points |
Kevin O'Connor | 47c8e31 | 2011-07-10 22:57:32 -0400 | [diff] [blame] | 316 | DECLFUNC entry_apm16 |
| 317 | entry_apm16: |
Kevin O'Connor | 1d01951 | 2008-03-11 21:21:47 -0400 | [diff] [blame] | 318 | pushfw // save flags |
| 319 | pushl %eax // dummy |
Kevin O'Connor | c003148 | 2010-01-01 13:03:17 -0500 | [diff] [blame] | 320 | ENTRY_ARG handle_apm16 |
Kevin O'Connor | b3c28be | 2008-06-08 13:34:43 -0400 | [diff] [blame] | 321 | addw $4, %sp // pop dummy |
Kevin O'Connor | 1d01951 | 2008-03-11 21:21:47 -0400 | [diff] [blame] | 322 | popfw // restore flags |
| 323 | lretw |
| 324 | |
| 325 | .code32 |
Kevin O'Connor | 47c8e31 | 2011-07-10 22:57:32 -0400 | [diff] [blame] | 326 | DECLFUNC entry_apm32 |
| 327 | entry_apm32: |
Kevin O'Connor | c003148 | 2010-01-01 13:03:17 -0500 | [diff] [blame] | 328 | pushfl |
| 329 | pushl %gs |
| 330 | pushl %cs // Move second descriptor after %cs to %gs |
| 331 | addl $16, (%esp) |
| 332 | popl %gs |
Kevin O'Connor | f3fe3aa | 2010-12-05 12:38:33 -0500 | [diff] [blame] | 333 | ENTRY_ARG_ESP _cfunc32seg_handle_apm32 |
Kevin O'Connor | c003148 | 2010-01-01 13:03:17 -0500 | [diff] [blame] | 334 | popl %gs |
| 335 | popfl |
Kevin O'Connor | 1d01951 | 2008-03-11 21:21:47 -0400 | [diff] [blame] | 336 | lretl |
Kevin O'Connor | ee4f9ff | 2008-07-05 21:19:10 -0400 | [diff] [blame] | 337 | |
Kevin O'Connor | 871e0a0 | 2009-12-30 12:14:53 -0500 | [diff] [blame] | 338 | // PCI-BIOS 32bit entry point |
Kevin O'Connor | 47c8e31 | 2011-07-10 22:57:32 -0400 | [diff] [blame] | 339 | DECLFUNC entry_pcibios32 |
| 340 | entry_pcibios32: |
Kevin O'Connor | 871e0a0 | 2009-12-30 12:14:53 -0500 | [diff] [blame] | 341 | pushfl |
Kevin O'Connor | c003148 | 2010-01-01 13:03:17 -0500 | [diff] [blame] | 342 | pushl %gs // Backup %gs and set %gs=%ds |
| 343 | pushl %ds |
| 344 | popl %gs |
Kevin O'Connor | f3fe3aa | 2010-12-05 12:38:33 -0500 | [diff] [blame] | 345 | ENTRY_ARG_ESP _cfunc32seg_handle_pcibios32 |
Kevin O'Connor | 871e0a0 | 2009-12-30 12:14:53 -0500 | [diff] [blame] | 346 | popl %gs |
| 347 | popfl |
| 348 | lretl |
| 349 | |
| 350 | // BIOS32 support |
Kevin O'Connor | 47c8e31 | 2011-07-10 22:57:32 -0400 | [diff] [blame] | 351 | EXPORTFUNC entry_bios32 |
| 352 | entry_bios32: |
Kevin O'Connor | 871e0a0 | 2009-12-30 12:14:53 -0500 | [diff] [blame] | 353 | pushfl |
| 354 | #if CONFIG_PCIBIOS |
| 355 | // Check for PCI-BIOS request |
| 356 | cmpl $0x49435024, %eax // $PCI |
| 357 | jne 1f |
| 358 | movl $BUILD_BIOS_ADDR, %ebx |
| 359 | movl $BUILD_BIOS_SIZE, %ecx |
Kevin O'Connor | 47c8e31 | 2011-07-10 22:57:32 -0400 | [diff] [blame] | 360 | movl $entry_pcibios32, %edx |
Kevin O'Connor | 871e0a0 | 2009-12-30 12:14:53 -0500 | [diff] [blame] | 361 | xorb %al, %al |
| 362 | jmp 2f |
| 363 | #endif |
| 364 | // Unknown request |
| 365 | 1: movb $0x80, %al |
| 366 | // Return to caller |
| 367 | 2: popfl |
| 368 | lretl |
| 369 | |
Kevin O'Connor | ee4f9ff | 2008-07-05 21:19:10 -0400 | [diff] [blame] | 370 | // 32bit elf entry point |
Kevin O'Connor | 47c8e31 | 2011-07-10 22:57:32 -0400 | [diff] [blame] | 371 | EXPORTFUNC entry_elf |
| 372 | entry_elf: |
Kevin O'Connor | ee4f9ff | 2008-07-05 21:19:10 -0400 | [diff] [blame] | 373 | cli |
| 374 | cld |
| 375 | lidtl (BUILD_BIOS_ADDR + pmode_IDT_info) |
| 376 | lgdtl (BUILD_BIOS_ADDR + rombios32_gdt_48) |
Kevin O'Connor | e0504b0 | 2009-04-13 19:32:51 -0400 | [diff] [blame] | 377 | movl $SEG32_MODE32_DS, %eax |
| 378 | movw %ax, %ds |
| 379 | movw %ax, %es |
| 380 | movw %ax, %fs |
| 381 | movw %ax, %gs |
| 382 | movw %ax, %ss |
Kevin O'Connor | ee4f9ff | 2008-07-05 21:19:10 -0400 | [diff] [blame] | 383 | movl $BUILD_STACK_ADDR, %esp |
Kevin O'Connor | 87b533b | 2011-07-10 22:35:07 -0400 | [diff] [blame] | 384 | ljmpl $SEG32_MODE32_CS, $_cfunc32flat_handle_post |
Kevin O'Connor | ee4f9ff | 2008-07-05 21:19:10 -0400 | [diff] [blame] | 385 | |
Kevin O'Connor | 1d01951 | 2008-03-11 21:21:47 -0400 | [diff] [blame] | 386 | .code16gcc |
Kevin O'Connor | 1d01951 | 2008-03-11 21:21:47 -0400 | [diff] [blame] | 387 | |
Kevin O'Connor | 38fcbfe | 2008-02-25 22:30:47 -0500 | [diff] [blame] | 388 | |
| 389 | /**************************************************************** |
Kevin O'Connor | c5b5036 | 2008-12-18 21:56:41 -0500 | [diff] [blame] | 390 | * Interrupt entry points |
| 391 | ****************************************************************/ |
| 392 | |
Kevin O'Connor | 9f193b9 | 2009-05-16 23:31:27 -0400 | [diff] [blame] | 393 | // Main entry point for interrupts without args |
| 394 | DECLFUNC irqentry |
| 395 | irqentry: |
| 396 | ENTRY_ST |
| 397 | iretw |
| 398 | |
| 399 | // Main entry point for interrupts with args |
Kevin O'Connor | eaec3c2 | 2009-05-30 03:40:22 -0400 | [diff] [blame] | 400 | DECLFUNC irqentryarg |
Kevin O'Connor | 9f193b9 | 2009-05-16 23:31:27 -0400 | [diff] [blame] | 401 | irqentryarg: |
| 402 | ENTRY_ARG_ST |
| 403 | iretw |
| 404 | |
Kevin O'Connor | 812478e | 2011-01-22 10:53:48 -0500 | [diff] [blame] | 405 | // Define an entry point for an interrupt (no args passed). |
| 406 | .macro IRQ_ENTRY num |
| 407 | .global entry_\num |
| 408 | entry_\num : |
| 409 | pushl $ handle_\num |
| 410 | jmp irqentry |
| 411 | .endm |
| 412 | |
| 413 | .macro DECL_IRQ_ENTRY num |
| 414 | DECLFUNC entry_\num |
| 415 | IRQ_ENTRY \num |
| 416 | .endm |
| 417 | |
| 418 | // Define an entry point for an interrupt (can read/modify args). |
| 419 | .macro IRQ_ENTRY_ARG num |
| 420 | .global entry_\num |
| 421 | entry_\num : |
| 422 | pushl $ handle_\num |
| 423 | jmp irqentryarg |
| 424 | .endm |
| 425 | |
| 426 | .macro DECL_IRQ_ENTRY_ARG num |
| 427 | DECLFUNC entry_\num |
| 428 | IRQ_ENTRY_ARG \num |
| 429 | .endm |
| 430 | |
| 431 | // Various entry points (that don't require a fixed location). |
Kevin O'Connor | d67a703 | 2009-01-17 19:37:26 -0500 | [diff] [blame] | 432 | DECL_IRQ_ENTRY_ARG 13 |
Kevin O'Connor | d67a703 | 2009-01-17 19:37:26 -0500 | [diff] [blame] | 433 | DECL_IRQ_ENTRY 76 |
Kevin O'Connor | d67a703 | 2009-01-17 19:37:26 -0500 | [diff] [blame] | 434 | DECL_IRQ_ENTRY 70 |
| 435 | DECL_IRQ_ENTRY 74 |
| 436 | DECL_IRQ_ENTRY 75 |
| 437 | DECL_IRQ_ENTRY hwpic1 |
| 438 | DECL_IRQ_ENTRY hwpic2 |
| 439 | |
Kevin O'Connor | 4ebc0b7 | 2009-03-01 12:31:57 -0500 | [diff] [blame] | 440 | // int 18/19 are special - they reset stack and call into 32bit mode. |
Kevin O'Connor | d67a703 | 2009-01-17 19:37:26 -0500 | [diff] [blame] | 441 | DECLFUNC entry_19 |
| 442 | entry_19: |
Kevin O'Connor | f3fe3aa | 2010-12-05 12:38:33 -0500 | [diff] [blame] | 443 | ENTRY_INTO32 _cfunc32flat_handle_19 |
Kevin O'Connor | d67a703 | 2009-01-17 19:37:26 -0500 | [diff] [blame] | 444 | |
| 445 | DECLFUNC entry_18 |
| 446 | entry_18: |
Kevin O'Connor | f3fe3aa | 2010-12-05 12:38:33 -0500 | [diff] [blame] | 447 | ENTRY_INTO32 _cfunc32flat_handle_18 |
Kevin O'Connor | d67a703 | 2009-01-17 19:37:26 -0500 | [diff] [blame] | 448 | |
| 449 | |
| 450 | /**************************************************************** |
| 451 | * Fixed position entry points |
| 452 | ****************************************************************/ |
| 453 | |
| 454 | // Specify a location in the fixed part of bios area. |
| 455 | .macro ORG addr |
| 456 | .section .fixedaddr.\addr |
| 457 | .endm |
| 458 | |
| 459 | ORG 0xe05b |
Kevin O'Connor | 87b533b | 2011-07-10 22:35:07 -0400 | [diff] [blame] | 460 | entry_post: |
| 461 | cmpl $0, %cs:HaveRunPost // Check for resume/reboot |
| 462 | jnz entry_resume |
| 463 | ENTRY_INTO32 _cfunc32flat_handle_post // Normal entry point |
Kevin O'Connor | d67a703 | 2009-01-17 19:37:26 -0500 | [diff] [blame] | 464 | |
Kevin O'Connor | c5b5036 | 2008-12-18 21:56:41 -0500 | [diff] [blame] | 465 | ORG 0xe2c3 |
Kevin O'Connor | 75f49b3 | 2009-03-07 00:07:24 -0500 | [diff] [blame] | 466 | IRQ_ENTRY 02 |
Kevin O'Connor | c5b5036 | 2008-12-18 21:56:41 -0500 | [diff] [blame] | 467 | |
Kevin O'Connor | 7453453 | 2008-05-12 18:28:58 -0400 | [diff] [blame] | 468 | ORG 0xe3fe |
Kevin O'Connor | b4f0e89 | 2008-12-13 18:33:05 -0500 | [diff] [blame] | 469 | .global entry_13_official |
| 470 | entry_13_official: |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 471 | jmp entry_13 |
| 472 | |
Kevin O'Connor | 3085376 | 2009-01-17 18:49:20 -0500 | [diff] [blame] | 473 | // 0xe401 - OldFDPT in disk.c |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 474 | |
Kevin O'Connor | 7453453 | 2008-05-12 18:28:58 -0400 | [diff] [blame] | 475 | ORG 0xe6f2 |
Kevin O'Connor | b4f0e89 | 2008-12-13 18:33:05 -0500 | [diff] [blame] | 476 | .global entry_19_official |
| 477 | entry_19_official: |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 478 | jmp entry_19 |
| 479 | |
Kevin O'Connor | 3085376 | 2009-01-17 18:49:20 -0500 | [diff] [blame] | 480 | // 0xe6f5 - BIOS_CONFIG_TABLE in misc.c |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 481 | |
Kevin O'Connor | 3085376 | 2009-01-17 18:49:20 -0500 | [diff] [blame] | 482 | // 0xe729 - BaudTable in serial.c |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 483 | |
Kevin O'Connor | 7453453 | 2008-05-12 18:28:58 -0400 | [diff] [blame] | 484 | ORG 0xe739 |
Kevin O'Connor | ed12849 | 2008-03-11 11:14:59 -0400 | [diff] [blame] | 485 | IRQ_ENTRY_ARG 14 |
| 486 | |
Kevin O'Connor | b4f0e89 | 2008-12-13 18:33:05 -0500 | [diff] [blame] | 487 | ORG 0xe82e |
| 488 | IRQ_ENTRY_ARG 16 |
| 489 | |
| 490 | ORG 0xe987 |
| 491 | IRQ_ENTRY 09 |
| 492 | |
| 493 | ORG 0xec59 |
| 494 | IRQ_ENTRY_ARG 40 |
| 495 | |
| 496 | ORG 0xef57 |
| 497 | IRQ_ENTRY 0e |
| 498 | |
Kevin O'Connor | 3085376 | 2009-01-17 18:49:20 -0500 | [diff] [blame] | 499 | // 0xefc7 - diskette_param_table in floppy.c |
Kevin O'Connor | b4f0e89 | 2008-12-13 18:33:05 -0500 | [diff] [blame] | 500 | |
| 501 | ORG 0xefd2 |
| 502 | IRQ_ENTRY_ARG 17 |
| 503 | |
| 504 | ORG 0xf045 |
Kevin O'Connor | d67a703 | 2009-01-17 19:37:26 -0500 | [diff] [blame] | 505 | entry_10_0x0f: |
Kevin O'Connor | b4f0e89 | 2008-12-13 18:33:05 -0500 | [diff] [blame] | 506 | // XXX - INT 10 Functions 0-Fh Entry Point |
| 507 | iretw |
| 508 | |
| 509 | ORG 0xf065 |
| 510 | IRQ_ENTRY_ARG 10 |
| 511 | |
Kevin O'Connor | 3085376 | 2009-01-17 18:49:20 -0500 | [diff] [blame] | 512 | // 0xf0a4 - VideoParams in misc.c |
Kevin O'Connor | b4f0e89 | 2008-12-13 18:33:05 -0500 | [diff] [blame] | 513 | |
Kevin O'Connor | b4f0e89 | 2008-12-13 18:33:05 -0500 | [diff] [blame] | 514 | ORG 0xf841 |
Kevin O'Connor | 9f193b9 | 2009-05-16 23:31:27 -0400 | [diff] [blame] | 515 | IRQ_ENTRY_ARG 12 |
Kevin O'Connor | b4f0e89 | 2008-12-13 18:33:05 -0500 | [diff] [blame] | 516 | |
| 517 | ORG 0xf84d |
Kevin O'Connor | 9f193b9 | 2009-05-16 23:31:27 -0400 | [diff] [blame] | 518 | IRQ_ENTRY_ARG 11 |
Kevin O'Connor | b4f0e89 | 2008-12-13 18:33:05 -0500 | [diff] [blame] | 519 | |
| 520 | ORG 0xf859 |
| 521 | IRQ_ENTRY_ARG 15 |
| 522 | |
Kevin O'Connor | 3085376 | 2009-01-17 18:49:20 -0500 | [diff] [blame] | 523 | // 0xfa6e - vgafont8 in font.c |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 524 | |
Kevin O'Connor | 7453453 | 2008-05-12 18:28:58 -0400 | [diff] [blame] | 525 | ORG 0xfe6e |
Kevin O'Connor | ed12849 | 2008-03-11 11:14:59 -0400 | [diff] [blame] | 526 | IRQ_ENTRY_ARG 1a |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 527 | |
Kevin O'Connor | 7453453 | 2008-05-12 18:28:58 -0400 | [diff] [blame] | 528 | ORG 0xfea5 |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 529 | IRQ_ENTRY 08 |
| 530 | |
Kevin O'Connor | 3085376 | 2009-01-17 18:49:20 -0500 | [diff] [blame] | 531 | // 0xfef3 - InitVectors in misc.c |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 532 | |
Kevin O'Connor | 3085376 | 2009-01-17 18:49:20 -0500 | [diff] [blame] | 533 | // 0xff00 - BiosCopyright in misc.c |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 534 | |
Kevin O'Connor | 7453453 | 2008-05-12 18:28:58 -0400 | [diff] [blame] | 535 | ORG 0xff53 |
Kevin O'Connor | d67a703 | 2009-01-17 19:37:26 -0500 | [diff] [blame] | 536 | .global entry_iret_official |
| 537 | entry_iret_official: |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 538 | iretw |
| 539 | |
Kevin O'Connor | 7453453 | 2008-05-12 18:28:58 -0400 | [diff] [blame] | 540 | ORG 0xff54 |
Kevin O'Connor | ed12849 | 2008-03-11 11:14:59 -0400 | [diff] [blame] | 541 | IRQ_ENTRY_ARG 05 |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 542 | |
Kevin O'Connor | 7453453 | 2008-05-12 18:28:58 -0400 | [diff] [blame] | 543 | ORG 0xfff0 // Power-up Entry Point |
Kevin O'Connor | 3f168b6 | 2008-11-29 13:22:29 -0500 | [diff] [blame] | 544 | .global reset_vector |
| 545 | reset_vector: |
Kevin O'Connor | 87b533b | 2011-07-10 22:35:07 -0400 | [diff] [blame] | 546 | ljmpw $SEG_BIOS, $entry_post |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 547 | |
Kevin O'Connor | 3085376 | 2009-01-17 18:49:20 -0500 | [diff] [blame] | 548 | // 0xfff5 - BiosDate in misc.c |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 549 | |
Kevin O'Connor | 3085376 | 2009-01-17 18:49:20 -0500 | [diff] [blame] | 550 | // 0xfffe - BiosModelId in misc.c |
Kevin O'Connor | e3677b1 | 2008-07-04 15:29:23 -0400 | [diff] [blame] | 551 | |
Kevin O'Connor | 3085376 | 2009-01-17 18:49:20 -0500 | [diff] [blame] | 552 | // 0xffff - BiosChecksum in misc.c |
Kevin O'Connor | f076a3e | 2008-02-25 22:25:15 -0500 | [diff] [blame] | 553 | |
| 554 | .end |