| /* SPDX-License-Identifier: GPL-2.0-only */ |
| |
| Device (DPTF) |
| { |
| Name (_HID, EISAID ("INT3400")) |
| Name (_UID, 0) |
| |
| Name (IDSP, Package() |
| { |
| /* DPPM Passive Policy 1.0 */ |
| ToUUID ("42A441D6-AE6A-462B-A84B-4A8CE79027D3"), |
| |
| /* DPPM Critical Policy */ |
| ToUUID ("97C68AE7-15FA-499c-B8C9-5DA81D606E0A"), |
| |
| /* DPPM Cooling Policy */ |
| ToUUID ("16CAF1B7-DD38-40ED-B1C1-1B8A1913D531"), |
| }) |
| |
| Method (_STA) |
| { |
| If (LEqual (\DPTE, One)) { |
| Return (0xF) |
| } Else { |
| Return (0x0) |
| } |
| } |
| |
| /* |
| * Arg0: Buffer containing UUID |
| * Arg1: Integer containing Revision ID of buffer format |
| * Arg2: Integer containing count of entries in Arg3 |
| * Arg3: Buffer containing list of DWORD capabilities |
| * Return: Buffer containing list of DWORD capabilities |
| */ |
| Method (_OSC, 4, Serialized) |
| { |
| /* Check for Passive Policy UUID */ |
| If (LEqual (DeRefOf (Index (IDSP, 0)), Arg0)) { |
| /* Initialize Thermal Devices */ |
| ^TINI () |
| |
| #ifdef DPTF_ENABLE_CHARGER |
| /* Initialize Charger Device */ |
| ^TCHG.INIT () |
| #endif |
| } |
| |
| Return (Arg3) |
| } |
| |
| /* Priority based _TRT */ |
| Name (TRTR, 1) |
| |
| Method (_TRT) |
| { |
| Return (\_SB.DTRT) |
| } |
| |
| /* Convert from Degrees C to 1/10 Kelvin for ACPI */ |
| Method (CTOK, 1) { |
| /* 10th of Degrees C */ |
| Multiply (Arg0, 10, Local0) |
| |
| /* Convert to Kelvin */ |
| Add (Local0, 2732, Local0) |
| |
| Return (Local0) |
| } |
| |
| /* Include CPU Participant */ |
| #include "cpu.asl" |
| |
| /* Include Thermal Participants */ |
| #include "thermal.asl" |
| |
| #ifdef DPTF_ENABLE_CHARGER |
| /* Include Charger Participant */ |
| #include "charger.asl" |
| #endif |
| } |